library ieee;
use ieee.std_logic_1164.all;
use ieee.numeric_std.all;

library osvvm; -- Utility Library
context osvvm.OsvvmContext;

use work.rtps_package.all;
use work.user_config.all;
use work.rtps_config_package.all;
use work.rtps_test_package.all;

-- This testbench tests the Liveliness handling of the RTPS Reader.
-- The testbench checks the memory contents at specific times, and also checks if the removal is propagated to the History Cache.

entity L0_rtps_reader_test3_m is
end entity;

architecture testbench of L0_rtps_reader_test3_m is
    
    -- *CONSTANT DECLARATION*
    constant MAX_REMOTE_ENDPOINTS    : natural := 3;
    constant ACCEPT_RES : std_logic_vector(WORD_WIDTH downto 0) := (others => '0');
    constant REJECT_RES : std_logic_vector(WORD_WIDTH downto 0) := (others => '1');
    
    -- *TYPE DECLARATION*
    type SEND_STAGE_TYPE is (IDLE, BUSY);
    type CHECK_STAGE_TYPE is (IDLE, CHECK, RESPONSE);
    type TEST_RAM_TYPE is array (0 to (MAX_REMOTE_ENDPOINTS*WRITER_ENDPOINT_FRAME_SIZE_A)-1) of std_logic_vector(WORD_WIDTH-1 downto 0);
    
    -- *SIGNAL DECLARATION*
    signal clk, empty_user, empty_meta, rd_user, rd_meta, last_word_in_user, last_word_in_meta : std_logic := '0';
    signal reset : std_logic := '1';
    signal data_in_user, data_in_meta, data_out_hc : std_logic_vector(WORD_WIDTH-1 downto 0) := (others => '0');
    signal start_hc, ack_hc, done_hc, done_hc_delay, ready_out_hc, valid_out_hc, last_word_out_hc : std_logic := '0';
    signal opcode_hc : HISTORY_CACHE_OPCODE_TYPE := NOP;
    signal ret_hc : HISTORY_CACHE_RESPONSE_TYPE := OK;
    signal test_time : TIME_TYPE := TIME_INVALID;
    signal stim_stage_user, stim_stage_meta : SEND_STAGE_TYPE := IDLE;
    signal check_stage : CHECK_STAGE_TYPE := IDLE;
    shared variable stimulus_user, stimulus_meta, reference : TEST_PACKET_TYPE := EMPTY_TEST_PACKET;
    signal packet_sent_user, packet_sent_meta : std_logic := '0';
    signal cnt_stim_meta, cnt_stim_user : natural := 0;
    signal start_meta, start_user : std_logic := '0';
    shared variable SB_out : osvvm.ScoreBoardPkg_slv.ScoreBoardPType;
    shared variable SB_mem : work.ScoreBoardPkg_MemoryTest.ScoreBoardPType;
    signal stim_done, mem_check_done, out_check_done, test_done, mem_check : std_logic := '0';
    
    -- *FUNCTION DECLARATION*
    function gen_sn(input : natural) return SEQUENCENUMBER_TYPE is
        variable ret : SEQUENCENUMBER_TYPE;
    begin
        ret(0)  := (others => '0');
        ret(1)  := unsigned(int(input, WORD_WIDTH));
        return ret;
    end function;
begin

    -- Unit Under Test
    uut : entity work.rtps_reader(arch)
        generic map (
            ENTITYID                    => DEFAULT_READER_ENTITYID,
            RELIABILTY_QOS              => RELIABLE_RELIABILITY_QOS,
            LIVELINESS_QOS              => MANUAL_BY_TOPIC_LIVELINESS_QOS,
            DURABILITY_QOS              => VOLATILE_DURABILITY_QOS,
            HEARTBEAT_RESPONSE_DELAY    => DURATION_ZERO,
            HEARTBEAT_SUPPRESSION_DELAY => DURATION_ZERO,
            LEASE_DURATION              => gen_duration(5,0),
            WITH_KEY                    => TRUE,
            MAX_REMOTE_ENDPOINTS        => MAX_REMOTE_ENDPOINTS
        )
        port map (
            -- SYSTEM
            clk                 => clk,
            reset               => reset,
            time                => test_time,
            empty_user          => empty_user or packet_sent_user,
            rd_user             => rd_user,
            data_in_user        => data_in_user,
            last_word_in_user   => last_word_in_user,
            empty_meta          => empty_meta or packet_sent_meta,
            rd_meta             => rd_meta,
            data_in_meta        => data_in_meta,
            last_word_in_meta   => last_word_in_meta,
            wr_rtps             => open,
            full_rtps           => '0',
            last_word_out_rtps  => open,
            data_out_rtps       => open,
            start_hc            => start_hc,
            opcode_hc           => opcode_hc,
            ack_hc              => ack_hc,
            done_hc             => done_hc,
            ret_hc              => ret_hc,
            data_out_hc         => data_out_hc,
            valid_out_hc        => valid_out_hc,
            ready_out_hc        => ready_out_hc,
            last_word_out_hc    => last_word_out_hc
        );
    
    stimulus_prc : process
        variable RV                     : RandomPType;
        variable p0, p1, p2             : PARTICIPANT_DATA_TYPE := DEFAULT_PARTICIPANT_DATA;
        variable e0, e1, e2, endpoint   : ENDPOINT_DATA_TYPE := DEFAULT_ENDPOINT_DATA;
        variable payload                : TEST_PACKET_TYPE := EMPTY_TEST_PACKET;
        variable sub                    : RTPS_SUBMESSAGE_TYPE := DEFAULT_RTPS_SUBMESSAGE;
        variable cc                     : CACHE_CHANGE_TYPE := DEFAULT_CACHE_CHANGE;
        
        alias mem_op_done is <<signal uut.mem_op_done : std_logic>>;
        alias idle_sig is <<signal uut.idle_sig : std_logic>>;
        
        -- Wrapper to use procedure as function
        impure function gen_rand_loc_2 return LOCATOR_TYPE is
            variable ret : LOCATOR_TYPE := EMPTY_LOCATOR;
        begin
            gen_rand_loc(RV, ret);
            return ret;
        end function;
        
        impure function gen_rand_guid_prefix return GUIDPREFIX_TYPE is
            variable ret : GUIDPREFIX_TYPE;
        begin
            ret := (0 => RV.RandSlv(WORD_WIDTH), 1 => RV.RandSlv(WORD_WIDTH), 2 => RV.RandSlv(WORD_WIDTH));
            return ret;
        end function;
        
        procedure start_meta_test is
        begin
            start_meta  <= '1';
            wait until rising_edge(clk);
            start_meta  <= '0';
            wait until rising_edge(clk);
        end procedure;
        
        procedure start_user_test is
        begin
            start_user  <= '1';
            wait until rising_edge(clk);
            start_user  <= '0';
            wait until rising_edge(clk);
        end procedure;
        
        procedure push_reference(accept : in BOOLEAN) is
        begin
            -- NOTE: First Word represents the Response that we will return.
            if (accept) then
                SB_out.Push(ACCEPT_RES);
            else
                SB_out.Push(REJECT_RES);
            end if;
            for i in 0 to reference.length-1 loop
                SB_out.Push(reference.last(i) & reference.data(i));
            end loop;
        end procedure;
        
        impure function gen_payload return TEST_PACKET_TYPE is
            variable ret : TEST_PACKET_TYPE := EMPTY_TEST_PACKET;
        begin
            for i in 0 to RV.RandInt(1,10) loop
                ret.data(ret.length) := RV.RandSlv(WORD_WIDTH);
                ret.length  := ret.length + 1;
            end loop;
            ret.last(ret.length-1) := '1';
            return ret;
        end function;
        
        impure function gen_key_hash return KEY_HASH_TYPE is
            variable ret : KEY_HASH_TYPE := (others => (others => '0'));
        begin
            for i in 0 to KEY_HASH_TYPE'length-1 loop
                ret(i) := RV.RandSlv(WORD_WIDTH);
            end loop;
            return ret;
        end function;
        
        procedure wait_on_meta_sent is
        begin
            wait until rising_edge(packet_sent_meta);
        end procedure;
        
        procedure wait_on_user_sent is
        begin
            wait until rising_edge(packet_sent_user);
        end procedure;
        
        procedure wait_on_out_check is
        begin
            if (out_check_done /= '1') then
                wait until out_check_done = '1';
            end if;
        end procedure;
        
        procedure wait_on_mem_check is
        begin
            if (mem_check_done /= '1') then
                wait until mem_check_done = '1';
            end if;
        end procedure;
        
        procedure wait_on_completion is
        begin
            if (test_done /= '1') then
                wait until test_done = '1';
            end if;
        end procedure;
        
        procedure wait_on_idle is
        begin
            if (idle_sig /= '1' or mem_op_done /= '1') then
                wait until idle_sig = '1' and mem_op_done = '1';
            end if;
        end procedure;
        
        
    begin
        
        SetAlertLogName("rtps_reader - (Manual by Topic Liveliness) - Level 0 - Liveliness Handling");
        SetAlertEnable(FAILURE, TRUE);
        SetAlertEnable(ERROR, TRUE);
        SetAlertEnable(WARNING, TRUE);
        SetLogEnable(DEBUG, FALSE);
        SetLogEnable(PASSED, FALSE);
        SetLogEnable(INFO, TRUE);
        RV.InitSeed(RV'instance_name);
        
        -- Participant 0
        p0              := DEFAULT_PARTICIPANT_DATA;
        p0.guidPrefix   := gen_rand_guid_prefix;
        -- Participant 1
        p1              := DEFAULT_PARTICIPANT_DATA;
        p1.guidPrefix   := gen_rand_guid_prefix;
        -- Participant 2
        p2              := DEFAULT_PARTICIPANT_DATA;
        p2.guidPrefix   := gen_rand_guid_prefix;
        
        -- Endpoint 1
        e0                      := DEFAULT_ENDPOINT_DATA;
        e0.entityid             := RV.RandSlv(ENTITYID_WIDTH);
        e0.participant          := p0;
        e0.unicastLocatorList   := (numLocators => int(1,CDR_LONG_WIDTH), locator => (0 => gen_rand_loc_2, others => EMPTY_LOCATOR));
        -- Endpoint 2
        e1                      := DEFAULT_ENDPOINT_DATA;
        e1.entityid             := RV.RandSlv(ENTITYID_WIDTH);
        e1.participant          := p1;
        e1.unicastLocatorList   := (numLocators => int(1,CDR_LONG_WIDTH), locator => (0 => gen_rand_loc_2, others => EMPTY_LOCATOR));
        -- Endpoint 3
        e2                      := DEFAULT_ENDPOINT_DATA;
        e2.entityid             := RV.RandSlv(ENTITYID_WIDTH);
        e2.participant          := p2;
        e2.unicastLocatorList   := (numLocators => int(1,CDR_LONG_WIDTH), locator => (0 => gen_rand_loc_2, others => EMPTY_LOCATOR));
        
        Log("Initiating Test", INFO);
        test_time   <= TIME_ZERO;
        stim_done   <= '0';
        start_meta  <= '0';
        start_user  <= '0';
        mem_check   <= '0';
        reset       <= '1';
        wait until rising_edge(clk);
        wait until rising_edge(clk);
        reset   <= '0';
        
        Log("Current Time: 0 s", INFO);
        wait until rising_edge(clk);
        
        Log("Insert Endpoint 0 Participant 0", INFO);
        endpoint        := e0;
        endpoint.nr     := 0;
        endpoint.match  := MATCH;
        gen_endpoint_match_frame(endpoint, stimulus_meta);
        SB_mem.Push(gen_writer_endpoint_mem_frame_a(endpoint));
        start_meta_test;
        wait_on_meta_sent;
        mem_check   <= '1';
        wait_on_mem_check;
        mem_check   <= '0';
        stimulus_meta   := EMPTY_TEST_PACKET;
        stimulus_user   := EMPTY_TEST_PACKET;
        reference       := EMPTY_TEST_PACKET;
        
        Log("Insert Endpoint 1 Participant 1", INFO);
        endpoint        := e1;
        endpoint.nr     := 1;
        endpoint.match  := MATCH;
        gen_endpoint_match_frame(endpoint, stimulus_meta);
        SB_mem.Push(gen_writer_endpoint_mem_frame_a(endpoint));
        start_meta_test;
        wait_on_meta_sent;
        mem_check   <= '1';
        wait_on_mem_check;
        mem_check   <= '0';
        stimulus_meta   := EMPTY_TEST_PACKET;
        stimulus_user   := EMPTY_TEST_PACKET;
        reference       := EMPTY_TEST_PACKET;
        
        Log("Insert Endpoint 2 Participant 2", INFO);
        endpoint        := e2;
        endpoint.nr     := 2;
        endpoint.match  := MATCH;
        gen_endpoint_match_frame(endpoint, stimulus_meta);
        SB_mem.Push(gen_writer_endpoint_mem_frame_a(endpoint));
        start_meta_test;
        wait_on_meta_sent;
        mem_check   <= '1';
        wait_on_mem_check;
        mem_check   <= '0';
        stimulus_meta   := EMPTY_TEST_PACKET;
        stimulus_user   := EMPTY_TEST_PACKET;
        reference       := EMPTY_TEST_PACKET;
        
        wait_on_idle;
        Log("Current Time: 1 s", INFO);
        test_time   <= gen_duration(1,0);
        wait until rising_edge(clk);
        
        Log("Accept Endpoint 0 sent DATA [SN 1]", INFO);
        endpoint            := e0;
        sub                 := DEFAULT_RTPS_SUBMESSAGE;
        sub.submessageID    := SID_DATA;
        sub.writerId        := endpoint.entityid;
        sub.readerId        := DEFAULT_READER_ENTITYID;
        sub.writerSN        := gen_sn(1);
        sub.flags(SUBMESSAGE_DATA_FLAG_POS) := '1';
        sub.data := gen_payload;
        gen_rtps_handler_out(sub, get_loc(endpoint), FALSE, TIME_INVALID, endpoint.participant.guidPrefix, stimulus_user);
        cc := gen_cache_change(sub);
        gen_add_cache_change_dds(cc, TIME_INVALID, endpoint.nr, reference);
        push_reference(TRUE);
        start_user_test;
        wait_on_user_sent;
        wait_on_out_check;
        stimulus_meta   := EMPTY_TEST_PACKET;
        stimulus_user   := EMPTY_TEST_PACKET;
        reference       := EMPTY_TEST_PACKET;
        
        wait_on_idle;
        Log("Current Time: 2 s", INFO);
        test_time   <= gen_duration(2,0);
        wait until rising_edge(clk);
        
        Log("Participant 1 Liveliness Update [Ignored]", INFO);
        gen_liveliness_update_frame(p1, stimulus_meta);
        start_meta_test;
        wait_on_meta_sent;
        stimulus_meta   := EMPTY_TEST_PACKET;
        stimulus_user   := EMPTY_TEST_PACKET;
        reference       := EMPTY_TEST_PACKET;
        
        wait_on_idle;
        Log("Current Time: 3 s", INFO);
        test_time   <= gen_duration(3,0);
        wait until rising_edge(clk);
        
        Log("Endpoint 2 HEARTBEAT Liveliness Update", INFO);
        endpoint            := e2;
        sub                 := DEFAULT_RTPS_SUBMESSAGE;
        sub.submessageID    := SID_HEARTBEAT;
        sub.writerId        := endpoint.entityid;
        sub.readerId        := DEFAULT_READER_ENTITYID;
        sub.firstSN         := gen_sn(0);
        sub.lastSN          := gen_sn(1);
        sub.flags(SUBMESSAGE_LIVELINESS_FLAG_POS)   := '1';
        gen_rtps_handler_out(sub, get_loc(endpoint), FALSE, TIME_INVALID, endpoint.participant.guidPrefix, stimulus_user);
        start_user_test;
        wait_on_user_sent;
        stimulus_meta   := EMPTY_TEST_PACKET;
        stimulus_user   := EMPTY_TEST_PACKET;
        reference       := EMPTY_TEST_PACKET;
        
        wait_on_idle;
        Log("Current Time: 5 s", INFO);
        test_time   <= gen_duration(5,0);
        wait until rising_edge(clk);
        
        Log("Check removal of Endpoint 1", INFO);
        endpoint        := e0;
        endpoint.nr     := 0;
        endpoint.match  := MATCH;
        SB_mem.Push(gen_writer_endpoint_mem_frame_a(endpoint));
        endpoint        := e1;
        endpoint.nr     := 1;
        endpoint.match  := UNMATCH;
        SB_mem.Push(gen_writer_endpoint_mem_frame_a(endpoint));
        endpoint        := e2;
        endpoint.nr     := 2;
        endpoint.match  := MATCH;
        SB_mem.Push(gen_writer_endpoint_mem_frame_a(endpoint));
        SB_out.Push("0" & std_logic_vector(to_unsigned(1, WORD_WIDTH)));
        wait_on_out_check;
        mem_check   <= '1';
        wait_on_mem_check;
        mem_check   <= '0';
        stimulus_meta   := EMPTY_TEST_PACKET;
        stimulus_user   := EMPTY_TEST_PACKET;
        reference       := EMPTY_TEST_PACKET;
        
        wait_on_idle;
        Log("Current Time: 6 s", INFO);
        test_time   <= gen_duration(6,0);
        wait until rising_edge(clk);
        
        Log("Check removal of Endpoint 0", INFO);
        endpoint        := e0;
        endpoint.nr     := 0;
        endpoint.match  := UNMATCH;
        SB_mem.Push(gen_writer_endpoint_mem_frame_a(endpoint));
        endpoint        := e1;
        endpoint.nr     := 1;
        endpoint.match  := UNMATCH;
        SB_mem.Push(gen_writer_endpoint_mem_frame_a(endpoint));
        endpoint        := e2;
        endpoint.nr     := 2;
        endpoint.match  := MATCH;
        SB_mem.Push(gen_writer_endpoint_mem_frame_a(endpoint));
        SB_out.Push("0" & std_logic_vector(to_unsigned(0, WORD_WIDTH)));
        wait_on_out_check;
        mem_check   <= '1';
        wait_on_mem_check;
        mem_check   <= '0';
        stimulus_meta   := EMPTY_TEST_PACKET;
        stimulus_user   := EMPTY_TEST_PACKET;
        reference       := EMPTY_TEST_PACKET;
        
        wait_on_idle;
        Log("Current Time: 8 s", INFO);
        test_time   <= gen_duration(8,0);
        wait until rising_edge(clk);
        
        Log("Check removal of Endpoint 1", INFO);
        endpoint        := e0;
        endpoint.nr     := 0;
        endpoint.match  := UNMATCH;
        SB_mem.Push(gen_writer_endpoint_mem_frame_a(endpoint));
        endpoint        := e1;
        endpoint.nr     := 1;
        endpoint.match  := UNMATCH;
        SB_mem.Push(gen_writer_endpoint_mem_frame_a(endpoint));
        endpoint        := e2;
        endpoint.nr     := 2;
        endpoint.match  := UNMATCH;
        SB_mem.Push(gen_writer_endpoint_mem_frame_a(endpoint));
        SB_out.Push("0" & std_logic_vector(to_unsigned(2, WORD_WIDTH)));
        wait_on_out_check;
        mem_check   <= '1';
        wait_on_mem_check;
        mem_check   <= '0';
        stimulus_meta   := EMPTY_TEST_PACKET;
        stimulus_user   := EMPTY_TEST_PACKET;
        reference       := EMPTY_TEST_PACKET;
        
        stim_done   <= '1';
        wait_on_completion;
        TranscriptOpen(RESULTS_FILE, APPEND_MODE);
        SetTranscriptMirror;
        ReportAlerts;
        TranscriptClose;
        std.env.stop;
        wait;
    end process;
    
    clock_prc : process
    begin
        clk <= '0';
        wait for 25 ns;
        clk <= '1';
        wait for 25 ns;
    end process;
    
    empty_meta_prc : process
    begin
        empty_meta  <= '0';
        wait until rd_meta = '1';
        wait until rising_edge(clk);
        empty_meta  <= '1';
        wait until rising_edge(clk);
    end process;
    
    empty_user_prc : process
    begin
        empty_user  <= '0';
        wait until rd_user = '1';
        wait until rising_edge(clk);
        empty_user  <= '1';
        wait until rising_edge(clk);
    end process;
    
    alert_prc : process(all)
    begin
        if rising_edge(clk) then
            alertif(empty_meta = '1' and rd_meta = '1', "Input FIFO read signal high while empty signal high (meta)", ERROR);
            alertif(empty_user = '1' and rd_user = '1', "Input FIFO read signal high while empty signal high (user)", ERROR);
        end if;
    end process;
    
    input_meta_prc : process(all)
    begin
        data_in_meta        <= stimulus_meta.data(cnt_stim_meta);
        last_word_in_meta   <= stimulus_meta.last(cnt_stim_meta);
        
        if rising_edge(clk) then
            if (reset = '1') then
                cnt_stim_meta       <= 0;
                stim_stage_meta     <= IDLE;
                packet_sent_meta    <= '1';
            else
                case (stim_stage_meta) is
                    when IDLE =>
                        if (start_meta = '1' and stimulus_meta.length /= 0) then
                            stim_stage_meta     <= BUSY;
                            packet_sent_meta    <= '0';
                        end if;
                    when BUSY =>
                        if (rd_meta = '1') then
                            if (cnt_stim_meta = stimulus_meta.length-1) then
                                stim_stage_meta     <= IDLE;
                                packet_sent_meta    <= '1';
                                cnt_stim_meta       <= 0;
                            else
                                cnt_stim_meta   <= cnt_stim_meta + 1;
                            end if;
                        end if;
                end case;
            end if;
        end if;
    end process;
    
    input_user_prc : process(all)
    begin
        data_in_user        <= stimulus_user.data(cnt_stim_user);
        last_word_in_user   <= stimulus_user.last(cnt_stim_user);
        
        if rising_edge(clk) then
            if (reset = '1') then
                cnt_stim_user       <= 0;
                stim_stage_user     <= IDLE;
                packet_sent_user    <= '1';
            else
                case (stim_stage_user) is
                    when IDLE =>
                        if (start_user = '1' and stimulus_user.length /= 0) then
                            stim_stage_user     <= BUSY;
                            packet_sent_user    <= '0';
                        end if;
                    when BUSY =>
                        if (rd_user = '1') then
                            if (cnt_stim_user = stimulus_user.length-1) then
                                stim_stage_user     <= IDLE;
                                packet_sent_user    <= '1';
                                cnt_stim_user       <= 0;
                            else
                                cnt_stim_user   <= cnt_stim_user + 1;
                            end if;
                        end if;
                end case;
            end if;
        end if;
    end process;
    
    done_proc : process(clk)
    begin
        if rising_edge(clk) then
            if (stim_done = '1' and SB_out.empty) then
                test_done   <= '1';
            else
                test_done   <= '0';
            end if;
        end if;
    end process;
    
    out_check_prc : process(all)
        variable accept : std_logic_vector(WORD_WIDTH downto 0);
    begin
        if rising_edge(clk) then
            case (check_stage) is
                when IDLE =>
                    out_check_done  <= '0';
                    if (start_hc = '1') then
                        check_stage <= CHECK;
                        case (opcode_hc) is
                            when REMOVE_WRITER =>
                                SB_out.Check(last_word_out_hc & data_out_hc);
                                accept      := ACCEPT_RES;
                                check_stage <= RESPONSE;
                            when ADD_CACHE_CHANGE =>
                                -- Pop Response Value
                                SB_out.pop(accept);
                            when others =>
                                Alert("Unexpected HC Opcode", ERROR);
                        end case;
                    end if;
                when CHECK =>
                    if (valid_out_hc = '1') then
                        SB_out.Check(last_word_out_hc & data_out_hc);
                        
                        if (last_word_out_hc = '1') then
                            check_stage     <= RESPONSE;
                        end if;
                    end if;
                when RESPONSE =>
                    check_stage     <= IDLE;
                    out_check_done  <= '1';
            end case;
        end if;
        -- DEFAULT
        ack_hc          <= '0';
        done_hc         <= '0';
        ret_hc          <= ERROR;
        ready_out_hc    <= '0';
        case (check_stage) is
            when IDLE =>
                if (start_hc = '1') then
                    ack_hc      <= '1';
                end if;
            when CHECK =>
                ready_out_hc    <= '1';
            when RESPONSE =>
                done_hc         <= '1';
                if (accept = ACCEPT_RES) then
                    ret_hc  <= OK;
                else
                    ret_hc  <= REJECTED;
                end if;
        end case;
    end process;
    
    mem_check_prc : process
        alias mem is <<signal uut.mem_ctrl_inst.ram_inst.mem : TEST_RAM_TYPE>>;
        alias mem_op_done is <<signal uut.mem_op_done : std_logic>>;
        alias idle_sig is <<signal uut.idle_sig : std_logic>>;
        variable reference : TEST_WRITER_ENDPOINT_MEMORY_FRAME_TYPE_A;
    begin
        mem_check_done  <= '0';
        -- SAFEGUARD: (Prevent Fall-through Behavior)
        if (reset /= '0') then
            wait until reset = '0';
        end if;
        -- Wait for Stimulus Process to give the go
        wait until rising_edge(mem_check);
        -- Wait for UUT IDLE state
        if (idle_sig /= '1') then
            wait until idle_sig = '1';
        end if;
        -- Wait for ongoing memory operation
        if (mem_op_done /= '1') then
            wait until mem_op_done = '1';
        end if;
        while (not SB_mem.empty) loop
            SB_mem.Pop(reference);
            for i in 0 to reference'length-1 loop
                AffirmIf(?? (mem(reference(i).addr) ?= reference(i).data), "Address: " & integer'image(reference(i).addr) & " Received: " & to_hstring(mem(reference(i).addr)) & " Expected: " & to_hstring(reference(i).data));
            end loop;
        end loop;
        -- Toggle High for one clock cycle
        mem_check_done  <= '1';
        wait until rising_edge(clk);
    end process;
    
    watchdog : process
    begin
        wait for 1 ms;
        Alert("Test timeout", FAILURE);
        std.env.stop;
    end process;
    
end architecture;